home *** CD-ROM | disk | FTP | other *** search
/ Aminet 21 / Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso / Aminet / comm / tcp / AminetFTPb.lha / AminetFTPb.yam < prev   
Text File  |  1997-08-23  |  7KB  |  241 lines
  1. /* $VER: AminetFTPb.yam 1.1 (23 AUG 97)
  2. ** by Charles Patterson <midian@azstarnet.com>
  3. ** http://www.azstarnet.com/~midian
  4. **
  5. ** Localization by Marc Hemes <marc.hemes@braunschweig.netsurf.de
  6. **
  7. ** Description: This script finds your "Today's Aminet Upload" email in
  8. **              YAM, lists the files so you can choose which ones you want
  9. **              to download, then uses AmFTP to download the selected files.
  10. **
  11. ** Requirements: YAM 1.3.4 (© 1995-96 Marcel Beck)
  12. **               TCP/IP Stack
  13. **               rexxreqtools.library 1.3 (© 1992-94 Rafael D'Halleweyn)
  14. **               AmFTP 1.75 (© 1995-97 Mathias Michler)
  15. **
  16. ** Instructions: Send email to listproc@mail.wustl.edu with the body:
  17. **                              SUBSCRIBE aminet-daily Your Name
  18. **                           or SUBSCRIBE aminet-weekly Your Name
  19. **               Copy this file to YAM:Rexx/
  20. **               Set FILES to the number of files you want listed at a time
  21. **               Open the YAM:.config file and add this line:
  22. **                              RexxMenu1 = YAM:Rexx/AminetFTP.yam
  23. **               Change the AMFTP, AMINET and LOCALDIR settings in script
  24. **               Download your email then run this script from the YAM
  25. **                  ARexx menu.
  26. **
  27. ** --- Files listed: --- */
  28. FILES = 10
  29.  
  30. /* --- Path to run AmFTP: --- */
  31. AMFTP="DH2:Applications/AmFTP/AmFTP"
  32.  
  33. /* --- Local Aminet Site: --- */
  34. AMINET="wuarchive.wustl.edu"
  35.  
  36. /* --- Local directory Site: --- */
  37. LOCALDIR="DH2:Lookat"
  38.  
  39. today = "Today's Aminet "
  40. weekly = "This week's Ami"
  41.  
  42. OPTIONS RESULTS
  43. ADDRESS YAM
  44.  
  45. IF ~SHOW('L','rexxsupport.library') THEN
  46.     ADDLIB('rexxsupport.library',0,-30,0)
  47.  
  48. IF ~SHOW('L','rexxreqtools.library') THEN
  49.     ADDLIB('rexxreqtools.library',0,-30,0)
  50.  
  51. NL = '0A'x
  52.  
  53. IF OPEN('localeprefs','ENV:sys/locale.prefs','R') THEN DO
  54.     language = SUBSTR(READCH('localeprefs', 113), 83, 29)
  55.     language = SUBSTR(language, 1, POS(D2C(0), language) - 1)
  56.     CLOSE('localeprefs')
  57. END
  58.  
  59. SELECT
  60.     WHEN language = 'deutsch' THEN DO  /* german text */
  61.         MSG_NOMAIL        = "Keine E-Mails im Ordner !"
  62.         MSG_ASKCHECK      = "Welche möchten Sie prüfen ?"
  63.         MSG_ASKCHECK_GAD  = "Heu_te|_Woche|Alle tä_glichen|Alle wöch_entlichen|_Alle|Abbru_ch"
  64.         MSG_MAILNOTFOUND  = "E-Mails mit Aminet-Uploads nicht gefunden !"
  65.         MSG_LISTFILES     = "Dateien aus welchen E-Mails auflisten ?"
  66.         MSG_LISTFILES_GAD = "Au_sgewählte|_Andere"
  67.         MSG_FILES         = "Dateinummern eingeben (z.B. 1 2 5)"
  68.         MSG_FILES_GAD     = "_Ok|_Fertig|_Abbruch"
  69.         MSG_README        = "Möchten Sie für jede Datei auch auch die zugehörigen .readme-Dateien ? "
  70.         MSG_README_GAD    = "_Ja|_Nein"
  71.     END
  72.     OTHERWISE DO /* english text */
  73.         MSG_NOMAIL        = "No email in folder!"
  74.         MSG_ASKCHECK      = "Do you wish to check"
  75.         MSG_ASKCHECK_GAD  = "_Today's|_Week's|All _dailys|All w_eeklys|_All|_Cancel"
  76.         MSG_MAILNOTFOUND  = "Aminet Uploads email not found!"
  77.         MSG_LISTFILES     = "List files in:"
  78.         MSG_LISTFILES_GAD = "_Selected|_Other"
  79.         MSG_FILES         = "Enter filenumbers (ie. 1 2 5)"
  80.         MSG_FILES_GAD     = "_Ok|_Finished|_Cancel"
  81.         MSG_README        = "Do you want each file's .readme as well?"
  82.         MSG_README_GAD    = "_Yes|_No"
  83.     END
  84. END
  85.  
  86. INFO SCREEN
  87. pubscreen = result
  88. GETFOLDERINFO MAX
  89. entries=result
  90. IF entries=0 THEN
  91.     DO
  92.         test=RTEZREQUEST(MSG_NOMAIL,"_Ok",,"rt_pubscrname="pubscreen)
  93.         EXIT
  94.     END
  95.  
  96. lfi = 0
  97. t = 0
  98. checkn = 0
  99. filename. = ''
  100. GETMAILINFO SUBJECT
  101. sub = LEFT(RESULT,15)
  102. IF sub = today | sub = weekly THEN
  103.     DO
  104.         test=RTEZREQUEST(MSG_LISTFILES,MSG_LISTFILES_GAD,,"rt_pubscrname="pubscreen)
  105.         lfi = rtresult
  106.     END
  107. IF lfi THEN
  108.     DO
  109.         t = 1
  110.         GETMAILINFO FILE
  111.         filename.1 = RESULT
  112.     END
  113. ELSE
  114.     DO
  115.         test=RTEZREQUEST(MSG_ASKCHECK,MSG_ASKCHECK_GAD,,"rt_pubscrname="pubscreen)
  116.         checkn = rtresult
  117.         IF checkn = 0 THEN EXIT
  118.         IF checkn = 1 | checkn = 3 THEN check = today
  119.         IF checkn = 2 | checkn = 4 THEN check = weekly
  120.         DO n = entries-1 TO 0 BY -1
  121.             SETMAIL n
  122.             GETMAILINFO SUBJECT
  123.             sub = LEFT(RESULT,15)
  124.             IF checkn = 5 THEN
  125.                 DO
  126.                     IF sub = today | sub = weekly THEN
  127.                         DO
  128.                             t = t + 1
  129.                             GETMAILINFO FILE
  130.                             filename.t = RESULT
  131.                         END
  132.                     END
  133.             ELSE
  134.                 IF sub = check THEN
  135.                     DO
  136.                         t = t + 1
  137.                         GETMAILINFO FILE
  138.                         filename.t = RESULT
  139.                     END
  140.         END
  141.     END
  142.  
  143. IF t = 0 THEN
  144.     DO
  145.         test=RTEZREQUEST(MSG_MAILNOTFOUND,"_Ok",,"rt_pubscrname="pubscreen)
  146.         EXIT
  147.     END
  148.  
  149. IF checkn < 3 THEN t = 1
  150.  
  151. DO mail = 1 to t
  152.     line. = ''
  153.     ADDRESS COMMAND 'COPY 'filename.mail' TO T:FTPMail.rct'
  154.     OPEN('recent','T:FTPMail.rct','R')
  155.  
  156.     DO UNTIL LEFT(READLN('recent'),3) = '|--'
  157.     END
  158.  
  159.     i=0
  160.     DO WHILE ~EOF('recent')
  161.         i=i+1
  162.         line.i=READLN('recent')
  163.         IF LEFT(line.i,1) = '|' THEN BREAK
  164.         IF STRIP(line.i) = '' THEN i=i-1
  165.     END
  166.     CLOSE('recent')
  167.  
  168.     c = 0
  169.     w = i%FILES
  170.     IF i//FILES >0 THEN w = w + 1
  171.  
  172.     DO n = 1 to w
  173.         DO f = n*FILES-(FILES-1) to n*FILES
  174.             PARSE VAR line.f file.f dir.f size.f '+' desc.f
  175.             file.f = LEFT(file.f,18,' ')
  176.             dir.f = LEFT(dir.f,10,' ')
  177.             size.f = RIGHT(size.f,4,' ')
  178.             desc.f = LEFT(desc.f,37,)
  179.         END
  180.  
  181.         reqstr = ''
  182.         DO x = f-FILES to f-1
  183.             y=x
  184.             if y<10 then y=' '||y
  185.             reqstr =  reqstr || y'. 'file.x' 'dir.x' 'size.x' 'desc.x||NL
  186.         END
  187.         input = RTGETSTRING(,reqstr,MSG_FILES,MSG_FILES_GAD,"rt_pubscrname="pubscreen)
  188.         IF rtresult = 2 THEN BREAK
  189.         DO WHILE input ~= ''
  190.             c = c+1
  191.             PARSE VAR input filenum.c input
  192.             j = filenum.c
  193.             IF STRIP(file.j) = '' THEN c = c-1
  194.         END
  195.     END
  196.  
  197.     close = 0
  198.     IF c > 0 THEN
  199.         DO
  200.             test=RTEZREQUEST(MSG_README,MSG_README_GAD,,"rt_pubscrname="pubscreen)
  201.             read = rtresult
  202.             IF ~SHOW('P',AMFTP.1) THEN
  203.                 DO
  204.                     ADDRESS COMMAND RUN AMFTP
  205.                     ADDRESS COMMAND WAITFORPORT AMFTP.1
  206.                     close=1
  207.                 END
  208.  
  209.             ADDRESS 'AMFTP.1'
  210.             CALL OPENPORT("AMFTP-RESULT.1")
  211.             CHANGELOCALDIR LOCALDIR
  212.             CONNECTHOST AMINET
  213.             WAITACTION "AMFTP-RESULT.1"
  214.             CALL WAITPKT "AMFTP-RESULT.1"
  215.             DO mc = 1 to c
  216.                 d = filenum.mc
  217.                 dir = "/pub/aminet/"||STRIP(dir.d)
  218.                 CHANGEDIR dir
  219.                 WAITACTION "AMFTP-RESULT.1"
  220.                 CALL WAITPKT "AMFTP-RESULT.1"
  221.                 'BATCH' file.d
  222.                 IF read THEN DO
  223.                     lgt = LENGTH(COMPRESS(file.d))-3
  224.                     filer = LEFT(file.d,lgt)||"readme"
  225.                     'BATCH' filer
  226.                 END
  227.                 PULL wait
  228.             END
  229.             RECEIVEBATCH
  230.             WAITACTION "AMFTP-RESULT.1"
  231.             CALL WAITPKT "AMFTP-RESULT.1"
  232.             'CLOSE'
  233.             CALL CLOSEPORT "AMFTP-RESULT.1"
  234.             IF close THEN QUIT
  235.         END
  236.  
  237. END
  238. ADDRESS COMMAND 'DELETE T:FTPMail.*'
  239. EXIT
  240.  
  241.